/*** ROUTINE DECLARATIONS ***/

ROUTINE
  darkq, ei8, scads, ctake, cdrop, scord, exitg, onlmp;


/*** DEAD-END ROUTINES ***/

PROMPT = Proc()
{
    $spec(HEADER, $sdesc($loc($ME))(1), $ME.pscore, $turns());
    "> ";
}

cg = Proc() {"Can't go that way.\n";}

tosml = Proc() {"The hole is too small for you to fit through.\n";}

dumdir = Proc() {"I don't know which direction that is.\n";}

tohigh = Proc() {"The hole is too high for you to reach.\n";}

nothe = Proc() {"This section is not implemented yet.\n";}

skore = Proc()
{
    "You scored ", $str($ME.pscore), " out of ", $str($ME.pmax),
	" possible points.\n";
}


VAR Rating[9];
(Rating+0) = "junior beginning";
(Rating+1) = "senior beginning";
(Rating+2) = "intermediate";
(Rating+3) = "expert";
(Rating+4) = "junior master";
(Rating+5) = "master";
(Rating+6) = "senior master";
(Rating+7) = "life master";
(Rating+8) = "super-stud";


ratng = Proc()
{
    $ME.ratvl = 0;
    If ($ME.pscore) {
	$ME.ratvl = ($ME.pscore * 8) / $ME.pmax;
    }
    "That gives you a ranking of ",
	Rating[$ME.ratvl],
	" adventurer.\n";
}


ratnx = Proc()
{
    If ($ME.ratvl == 8) {
	"CONGRATULATIONS.\n";
	$spec(QUIT);
    }
    $ME.ratvl = $ME.ratvl + 1;
    $ME.ratvl = $ME.ratvl * $ME.pmax;
    $ME.ratvl = $ME.ratvl / 8;
    $ME.ratvl = $ME.ratvl + 1;
    $ME.ratvl = $ME.ratvl - $ME.pscore;
    "To achieve the next higher rating, you need to score ",
	$str($ME.ratvl),
	" more points.\n";
}


endgame = Proc()
{
    $incturn();
    If ($ME.pscore == $ME.pmax) {
        "\tAs you drop the last treasure, the lights come up and you hear ",
        "a voice say, \"CONGRATULATIONS, ADVENTURER.  You have restored the ",
        "museum displays to their former glory.  Now accept the Director's ",
        "thanks, and also his reward!\"\n",
        "\tYou are miraculously transported to a room you have never seen ",
        "before, filled to the top with precious gold and jewels.  The voice ",
        "appears again, saying, \"Your reward is as follows:  you are ",
        "granted the privilege of becoming the new curator of the Museum.",
        "Your first responsibility is to catalog and sort these treasures ",
        "for placement in the Museum.  Your salary is $3.25 per hour.  ",
        "Again, thanks!\"\n",
        "\tThe voice disappears, and you are left alone in the immense room. ",
        "You'd better get to work, for you have a LOT to do!\n";
	$spec(QUIT);
    }
}